윈도우10 엣지 브라우저 완전히 삭제하는 방법

윈도우10의 기본 브라우저인 마이크로소프트 엣지는 크로미움 엔진을 기반으로 해서 같은 엔진 기반인 네이버의 웨일, 구글의 크롬과 차이점이 없어서 큰 메리트가 없습니다.

특히 Active-X와 같이 종속적인 서비스가 현재는 많이 줄어들어 있고 윈도우 기본 브라우저만 변경하면 크롬을 기본 브라우저로 대체할 수도 있기 때문에 다른 브라우저를 사용해도 불편함이 없는데요.

이렇게 메리트가 없는 만큼 엣지 브라우저를 완전히 삭제해서 용량을 세이브하고 싶은 사용자는 제어판에서 엣지 브라우저가 삭제되지 않기 때문에 cmd 명령어를 이용해 엣지 브라우저를 완전히 삭제할 수 있습니다.

윈도우10 cmd로 엣지 브라우저 완전히 삭제하기

1. 엣지 브라우저가 설치된 경로로 이동한 다음 최신 버전의 폴더를 더블 클릭합니다.

💡 엣지 브라우저의 설치 경로는 C:\Program Files (x86)\Microsoft\Edge\Application 입니다.

2. Installer 폴더로 이동합니다.

3. 탐색기 상단 메뉴에서 파일 > Windows Powershell 열기 > 관리자 권한으로 Windows Powershell 열기를 선택합니다.

4. cmd를 입력해 파워쉘을 명령 프롬프트로 전환합니다.

5. 엣지 제거 명령어를 입력합니다.

setup --uninstall --force-uninstall --system-level

6. 엣지가 설치된 경로 상위 폴더로 이동한 다음 남아있는 Edge 폴더를 삭제합니다.

엣지 삭제 후 정리할 찌꺼기 폴더 경로

• C:\Program Files (x86)\Microsoft\Edge

7. 윈도우10 기본 브라우저를 변경합니다.

엣지 브라우저가 기본 브라우저로 설정되어 있다면 엣지를 삭제했을 때 웹 페이지를 열 수 없기 때문에 크롬, 웨일등의 브라우저를 기본 브라우저로 지정합니다.

윈도우 설정의 앱 및 기능으로 이동한 다음 기본 앱 항목에서 웹 브라우저를 선택 후 사용자가 원하는 브라우저를 지정하면 되겠습니다.

그리고 Windows 검색에서 검색 결과로 나타나는 Bing 검색 섹션을 클릭했을 때 열리는 기본 브라우저 또한 엣지 브라우저이기 때문에 Windows 검색에서 열어 볼 브라우저를 변경해야 합니다.

엣지 삭제 cmd 배치 활용하기

첫번째 방법으로 사용자가 직접 명령어를 입력해 엣지를 삭제할 수 있지만 명령어를 자동으로 실행해주는 Batch를 이용해 클릭 한 번으로 자동 삭제를 할 수 있습니다.

1. 메모장을 실행합니다.
2. Batch 명령어를 복사해 붙여넣습니다.
3. 메모장의 메뉴에서 파일 > 다른 이름으로 저장을 선택합니다.
4. 파일 형식을 ‘모든 파일’로 변경 후 파일 확장자를 .bat으로 저장합니다.
5. 저장된 .bat 파일을 관리자 권한으로 실행합니다.

@setlocal DisableDelayedExpansion
@echo off
if defined PROCESSOR_ARCHITEW6432 start %SystemRoot%\Sysnative\cmd.exe /c "%0 " &exit
reg.exe query "HKU\S-1-5-19" 1>nul 2>nul || (echo Run the script as administrator&goto :TheEnd)

set "u_path=%LocalAppData%\Microsoft"
set "s_path=%ProgramFiles(x86)%\Microsoft"
if /i %PROCESSOR_ARCHITECTURE%==x86 (if not defined PROCESSOR_ARCHITEW6432 (
  set "s_path=%ProgramFiles%\Microsoft"
  )
)

@cls
echo.
choice /C YN /N /M "Microsoft Edge Chromium will be unintalled. Continue? [y/n]: "
if errorlevel 2 exit

reg delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Microsoft Edge" /v NoRemove /f 2>nul
reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Microsoft Edge" /v NoRemove /f 2>nul
reg delete "HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Microsoft Edge" /v NoRemove /f 2>nul

echo.
for /D %%i in ("%u_path%\Edge SxS\Application\*") do if exist "%%i\installer\setup.exe" (
echo Canary...
start "" /w "%%i\installer\setup.exe" --uninstall --msedge-sxs --verbose-logging --force-uninstall --delete-profile
)
for /D %%i in ("%u_path%\Edge Internal\Application\*") do if exist "%%i\installer\setup.exe" (
echo Internal...
start "" /w "%%i\installer\setup.exe" --uninstall --msedge-internal --verbose-logging --force-uninstall --delete-profile
)
for /D %%i in ("%u_path%\Edge Dev\Application\*") do if exist "%%i\installer\setup.exe" (
echo Dev...
start "" /w "%%i\installer\setup.exe" --uninstall --msedge-dev --verbose-logging --force-uninstall --delete-profile
)
for /D %%i in ("%u_path%\Edge Beta\Application\*") do if exist "%%i\installer\setup.exe" (
echo Beta...
start "" /w "%%i\installer\setup.exe" --uninstall --msedge-beta --verbose-logging --force-uninstall --delete-profile
)
for /D %%i in ("%u_path%\Edge\Application\*") do if exist "%%i\installer\setup.exe" (
echo Stable...
start "" /w "%%i\installer\setup.exe" --uninstall --verbose-logging --force-uninstall --delete-profile
)
for /D %%i in ("%u_path%\EdgeWebView\Application\*") do if exist "%%i\installer\setup.exe" (
echo WebView2 Runtime...
start "" /w "%%i\installer\setup.exe" --uninstall --msedgewebview --verbose-logging --force-uninstall --delete-profile
)

for /D %%i in ("%s_path%\EdgeWebView\Application\*") do if exist "%%i\installer\setup.exe" (
echo WebView2 Runtime...
start "" /w "%%i\installer\setup.exe" --uninstall --msedgewebview --system-level --verbose-logging --force-uninstall --delete-profile
)
for /D %%i in ("%s_path%\Edge\Application\*") do if exist "%%i\installer\setup.exe" (
echo Stable...
start "" /w "%%i\installer\setup.exe" --uninstall --system-level --verbose-logging --force-uninstall --delete-profile
)
for /D %%i in ("%s_path%\Edge Beta\Application\*") do if exist "%%i\installer\setup.exe" (
echo Beta...
start "" /w "%%i\installer\setup.exe" --uninstall --msedge-beta --system-level --verbose-logging --force-uninstall --delete-profile
)
for /D %%i in ("%s_path%\Edge Dev\Application\*") do if exist "%%i\installer\setup.exe" (
echo Dev...
start "" /w "%%i\installer\setup.exe" --uninstall --msedge-dev --system-level --verbose-logging --force-uninstall --delete-profile
)
for /D %%i in ("%s_path%\Edge Internal\Application\*") do if exist "%%i\installer\setup.exe" (
echo Internal...
start "" /w "%%i\installer\setup.exe" --uninstall --msedge-internal --system-level --verbose-logging --force-uninstall --delete-profile
)

del /f /q "%AppData%\Microsoft\Internet Explorer\Quick Launch\Microsoft Edge*.lnk" 2>nul
del /f /q "%SystemRoot%\System32\config\systemprofile\AppData\Roaming\Microsoft\Internet Explorer\Quick Launch\Microsoft Edge*.lnk" 2>nul

reg add "HKLM\SOFTWARE\Microsoft\EdgeUpdate" /v DoNotUpdateToEdgeWithChromium /t REG_DWORD /d 1 /f 1>nul

:TheEnd
echo.
echo Press any key to exit.
pause >nul
exit