작업표시줄의 알림창 영역에 표시되는 시스템 트레이 아이콘(모서리 아이콘)은 백그라운드에서 항상 싱행중이 앱의 아이콘이 표시되는 공간으로 이 영역의 아이콘이 많아지면 숨겨진 아이콘으로 그룹화되어 숨겨져 표시됩니다.
한번이라도 표시된 아이콘이 모서리 오버플로 목록에 표시되며 숨겨진 모서리 아이콘을 보이게 하거나 삭제하기 위해서는 Windows 설정의 기타 시스템 트레이 아이콘(모서리 오버플로) 옵션을 활용하면 되는데요.
삭제한 프로그램이나 더이상 사용하지 않는 포터블 프로그램등 여태까지 트레이 영역에 표시된 아이콘이 목록에 표시되는데, 기타 시스템 트레이 아이콘 목록이 지저분한 경우 트레이 아이콘 목록을 초기화 해서 사용할 수 있습니다.
튜토리얼 환경 : 윈도우11 21H2
목차
윈도우11 시스템 트레이 아이콘 목록 삭제
- Win + R 키를 눌러 실행창을 엽니다.
regedit을 입력해 레지스트리 편집기를 실행합니다.- 사용자 계정 컨트롤 화면에서 ‘예’ 버튼을 클릭해 관리자 권한으로 엽니다.
컴퓨터\HKEY_CURRENT_USER\Software\Classes\Local Settings\Software\Microsoft\Windows\CurrentVersion\TrayNotify- 모서리 오버플로 설정의 아이콘 목록 값이 저장된 레지스트리 경로로 이동합니다.
IconStreams,PastIconsStream값 두개를 Ctrl 키를 눌러 선택합니다.- 선택한 값을 우클릭한 후 컨텍스트 메뉴에서 삭제를 선택해 두 값을 삭제합니다.
- PC를 재부팅하거나 탐색기를 재시작해서 설정을 적용합니다.
윈도우11 기타 시스템 트레이 아이콘 초기화 Batch 적용
모서리 오버플로 목록이 지저분할 때 첫번째 방법으로 레지스트리 값을 삭제해도 되지만 매번 경로를 찾아가는게 번거로운 경우에는 아이콘 목록을 재설정하는 bat를 이용하면 아이콘 목록을 깔끔하게 초기화할 수 있습니다.
- 모서리 오버플로 아이콘 재설정 Bat 파일을 다운로드 받습니다.
- 현재 PC에 열려있는 작업물을 저장한 후 Bat 파일을 실행합니다.
- 명령 프롬프트 화면에서 ‘계속하려면 아무 키나 누르십시오’가 출력되면 아무 키나 눌러 명령어를 실행합니다.
- Do you want to restart the PC now? 가 출력되면 Y 또는 N을 눌러 선택합니다.
💡 PC를 재부팅하지 않아도 모서리 오버플로 아이콘 목록이 초기화 되지만 되도록이면 PC를 재부팅하는 것이 좋습니다.
출처 : ElevenForum
만일 파일을 다운로드 받을 수 없는 환경이면 아래 Batch를 메모장에 붙여넣어 .bat 파일로 만들어 실행하면 되겠습니다.
@echo off
set regPath=HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\CurrentVersion\TrayNotify
set regKey1=IconStreams
set regKey2=PastIconsStream
echo.
echo The explorer process must be temporarily killed before deleting your taskbar corner overflow notification icons cache.
echo.
echo Please SAVE ALL OPEN WORK before continuing.
echo.
pause
echo.
taskkill /IM explorer.exe /F
echo.
FOR /F "tokens=*" %%a in ('Reg Query "%regpath%" /v %regkey1% ^| find /i "%regkey1%"') do goto IconStreams
echo Registry key "IconStreams" already deleted.
echo.
:verify-PastIconsStream
FOR /F "tokens=*" %%a in ('Reg Query "%regpath%" /v %regkey2% ^| find /i "%regkey2%"') do goto PastIconsStream
echo Registry key "PastIconsStream" already deleted.
echo.
goto restart
:IconStreams
reg delete "%regpath%" /f /v "%regkey1%"
goto verify-PastIconsStream
:PastIconsStream
reg delete "%regpath%" /f /v "%regkey2%"
:restart
echo.
echo.
echo You will need to restart the PC to finish resetting your taskbar corner overflow notification icons.
echo.
CHOICE /C:YN /M "Do you want to restart the PC now?"
IF ERRORLEVEL 2 goto no
IF ERRORLEVEL 1 goto yes
:no
echo.
echo.
echo Restarting explorer....
echo.
echo Please remember to restart the PC later to finish resetting your taskbar corner overflow notification icons.
echo.
start explorer.exe
pause
exit /B
:yes
shutdown /r /f /t 00
